Съдържание

# Финансови функции, първа част

Тази категория съдържа математическите финансови функции на LibreOffice Calc.

## ACCRINT

Връща натрупаната лихва за ценна книга, която изплаща периодична лихва.

#### Синтаксис

ACCRINT(ДатаНаИздаване; ПърваЛихва; Сделка; Лихва; [Номинал]; Честота [; Основа)

ДатаНаИздаване (задължителен) е датата на издаването на ценната книга.

ПърваЛихва (задължителен) е датата на първата лихва на ценната книга.

Сделка (задължителен) е датата, за която трябва да бъде изчислена натрупаната до момента лихва.

Лихва (задължителен) е годишната лихва на купона на ценната книга.

Номинал (незадължителен) е номиналната стойност на ценната книга. Ако бъде пропуснат, се подразбира стойност 1000.

Препоръчваме винаги да задавате желаната от вас стойност за параметъра Номинал на ACCRINT, вместо да оставяте на Calc да попълни произволна подразбирана стойност. Така формулата ви ще бъде по-разбираема и по-лесна за поддръжка.

Честота (задължителен) е броят на купонните плащания за една година (1, 2 или 4).

Основа (незадължителен) се избира измежду няколко фиксирани възможности и указва как да се изчислява годината.

Основа | Пресмятане
--- | ---
0 или липсва | Американски метод (NASD) – 12 месеца с по 30 дни
1 | Точен брой дни в месеците, точен брой дни в година
2 | Точен брой дни в месеца, годината има 360 дни
3 | Точен брой дни в месеца, годината има 365 дни
4 | Европейски метод, 12 месеца по 30 дни всеки

#### Пример

Ценната книга е издадена на 28.02.2001 г. Датата на първата лихва е 31.08.2001 г. Датата на сделката е 01.05.2001 г. Лихвата е 0,1 или 10%, а номиналът е 1000 парични единици. Лихвата се плаща два пъти годишно (честотата е 2). Базата се взима по американския метод (0). Колко лихва е натрупана?

=ACCRINT("28.2.2001";"31.8.2001";"1.5.2001";0.1;1000;2;0) връща 16,94444.

## ACCRINTM

Връща натрупаната лихва за ценна книга, която изплаща лихва при падежа.

#### Синтаксис

ACCRINTM(ДатаНаИздаване; Сделка; Лихва [; Номинал [; Основа]])

ДатаНаИздаване (задължителен) е датата на издаването на ценната книга.

Сделка (задължителен) е датата, за която трябва да бъде изчислена натрупаната до момента лихва.

Лихва (задължителен) е годишната лихва на купона на ценната книга.

Номинал (незадължителен) е номиналната стойност на ценната книга. Ако бъде пропуснат, се подразбира стойност 1000.

Препоръчваме винаги да задавате желаната от вас стойност за параметъра Номинал на ACCRINTM, вместо да оставяте на Calc да попълни произволна подразбирана стойност. Така формулата ви ще бъде по-разбираема и по-лесна за поддръжка.

Основа (незадължителен) се избира измежду няколко фиксирани възможности и указва как да се изчислява годината.

Основа | Пресмятане
--- | ---
0 или липсва | Американски метод (NASD) – 12 месеца с по 30 дни
1 | Точен брой дни в месеците, точен брой дни в година
2 | Точен брой дни в месеца, годината има 360 дни
3 | Точен брой дни в месеца, годината има 365 дни
4 | Европейски метод, 12 месеца по 30 дни всеки

#### Пример

Ценната книга е издадена на 01.04.2001 г. Датата на падежа е 15.06.2001 г. Лихвата е 0,1 или 10%, а номиналът е 1000 парични единици. Основата за дневно/годишно изчисление е дневният баланс (3). Колко лихва е натрупана?

=ACCRINTM("1.4.2001";"15.6.2001";0,1;1000;3) връща 20,54795.

## AMORDEGRC

Изчислява амортизация за счетоводен период по дегресивен метод. За разлика от AMORLINC, тук се използва коефициент, независим от амортизационния срок.

#### Синтаксис

AMORDEGRC(ОтчСтойност; ДатаНаЗакупуване; ПървиПериод; ЛиквСтойност; Период; Норма [; Основа])

ОтчСтойност е отчетната стойност на актива.

ДатаНаЗакупуване е датата на придобиване.

ПървиПериод е крайната дата на първия счетоводен период.

ЛиквСтойност е ликвидационната стойност на актива в края на амортизационния срок.

Период е отчетният период, за който се изчислява.

Норма е нормата на амортизация.

Основа (незадължителен) се избира измежду няколко фиксирани възможности и указва как да се изчислява годината.

Основа | Пресмятане
--- | ---
0 или липсва | Американски метод (NASD) – 12 месеца с по 30 дни
1 | Точен брой дни в месеците, точен брой дни в година
2 | Точен брой дни в месеца, годината има 360 дни
3 | Точен брой дни в месеца, годината има 365 дни
4 | Европейски метод, 12 месеца по 30 дни всеки

#### Пример

Актив е придобит на 2020-02-01 за 2000 парични единици. Крайната дата на първия счетоводен период е 2020-12-31. Ликвидационната стойност на актива в края на амортизационния срок ще бъде 10 парични единици. Нормата на амортизация е 0,1 (10%) и годината се изчислява по метода за САЩ (основа 0). Ако използваме дегресивен метод, колко е амортизацията за четвъртия период?

=AMORDEGRC(2000; "2020-02-01"; "2020-12-31"; 10; 4; 0,1; 0) връща амортизация от 163 парични единици.

Имайте предвид, че основа 2 не се поддържа от Microsoft Excel. Ако използвате основа 2 и експортирате документа във формат XLSX, това ще предизвика грешка при отваряне в Excel.

## AMORLINC

Изчислява амортизация за счетоводен период по линеен метод. Ако активът е закупен по време на счетоводния период, се взима предвид пропорционалната част от амортизацията.

#### Синтаксис

AMORLINC(ОтчСтойност; ДатаНаЗакупуване; ПървиПериод; ЛиквСтойност; Период; Норма [; Основа])

ОтчСтойност е отчетната стойност на актива.

ДатаНаЗакупуване е датата на придобиване.

ПървиПериод е крайната дата на първия счетоводен период.

ЛиквСтойност е ликвидационната стойност на актива в края на амортизационния срок.

Период е отчетният период, за който се изчислява.

Норма е нормата на амортизация.

Основа (незадължителен) се избира измежду няколко фиксирани възможности и указва как да се изчислява годината.

Основа | Пресмятане
--- | ---
0 или липсва | Американски метод (NASD) – 12 месеца с по 30 дни
1 | Точен брой дни в месеците, точен брой дни в година
2 | Точен брой дни в месеца, годината има 360 дни
3 | Точен брой дни в месеца, годината има 365 дни
4 | Европейски метод, 12 месеца по 30 дни всеки

#### Пример

Актив е придобит на 2020-02-01 за 2000 парични единици. Крайната дата на първия счетоводен период е 2020-12-31. Ликвидационната стойност на актива в края на амортизационния срок ще бъде 10 парични единици. Нормата на амортизация е 0,1 (10%) и годината се изчислява по метода за САЩ (основа 0). Ако използваме линеен метод, колко е амортизацията за четвъртия период?

=AMORLINC(2000; "2020-02-01"; "2020-12-31"; 10; 4; 0,1; 0) връща амортизация от 200 парични единици.

Имайте предвид, че основа 2 не се поддържа от Microsoft Excel. Ако използвате основа 2 и експортирате документа във формат XLSX, това ще предизвика грешка при отваряне в Excel.

## DB

Изчислява амортизацията на актив за избран период по метода на фиксирано намаляване на остатъка (геометрично дегресивен метод).

Този метод за изчисляване се използва, ако искате да получите по-висока амортизация в началото на живота на актива (в сравнение с линейния метод). Стойността за амортизиране се намалява във всеки следващ период с общата амортизация от предишните периоди.

#### Синтаксис

DB(ОтчСтойност; ЛиквСтойност; Срок; Период [; Месец])

ОтчСтойност е началната стойност на актива.

ЛиквСтойност е ликвидационната стойност на актива в края на амортизационния срок.

Срок е броят периоди, за който активът се обезценява.

Период е дължината на периодите. Тя трябва да е в същите единици, както и амортизационният срок.

Месец (незадължителен) определя броя месеци в първата година от амортизационния срок. Ако не е зададен, се подразбира 12.

#### Пример

Компютър с начална стойност 25 000 парични единици трябва да се амортизира за срок от три години. Ликвидационната стойност трябва да е 1000 парични единици. Първият период на амортизацията обхваща 6 месеца. Каква е амортизацията на компютъра по метода на фиксирано намаляване на остатъка за втория период, който е пълна година, започваща от края на първия, шестмесечен период?

=DB(25000; 1000; 3; 2; 6) връща 11 037,95 парични единици.

## DDB

Изчислява амортизацията на актив за зададен период по аритметично дегресивен метод (метод на намаляващата се сума на числата).

Този метод за изчисляване е подходящ, ако желаете по-висока начална стойност на амортизацията в сравнение с линейния метод. Стойността на амортизацията намалява с всеки следващ период – това обикновено се използва за активи, които се обезценяват най-бързо скоро след закупуването си (превозни средства, компютри и т.н.). Обърнете внимание, че при този метод остатъчната стойност не може да достигне 0.

#### Синтаксис

DDB(ОтчСтойност; ЛиквСтойност; Срок; Период [; Коефициент])

ОтчСтойност е началната стойност на актива.

ЛиквСтойност е ликвидационната стойност на актива в края на амортизационния срок.

Срок е броят периоди (например години или месеци) в полезния живот на актива.

Период е периодът, за който да бъде изчислена стойността.

Коефициент (незадължителен) е коефициентът за намаляване на остатъка. Ако не е въведена стойност, се подразбира 2.

#### Пример

Компютър с начална стойност 75 000 парични единици трябва да се амортизира месечно в течение на 5 години. Стойността в края на амортизационния срок е 1 парична единица. Коефициентът е 2.

=DDB(75000;1;60;12;2) = 1721,81 парични единици, тоест амортизацията през дванадесетия месец след закупуването е 1721,81 парични единици.

## DISC

Връща дисконтовата ставка на ценна книга в проценти.

#### Синтаксис

DISC(Сделка; Падеж; Цена; ПогСтойност [; Основа])

Сделка е датата на закупуване на ценната книга.

Падеж е датата на падежа на ценната книга, когато срокът й изтича.

Цена е цената на книгата за 100 парични единици от номиналната стойност.

ПогСтойност е погасителната стойност на книгата за 100 парични единици от номиналната стойност.

Основа (незадължителен) се избира измежду няколко фиксирани възможности и указва как да се изчислява годината.

Основа | Пресмятане
--- | ---
0 или липсва | Американски метод (NASD) – 12 месеца с по 30 дни
1 | Точен брой дни в месеците, точен брой дни в година
2 | Точен брой дни в месеца, годината има 360 дни
3 | Точен брой дни в месеца, годината има 365 дни
4 | Европейски метод, 12 месеца по 30 дни всеки

#### Пример

Ценната книга е закупена на 25.01.2001 г., а падежът е на 15.11.2001 г. Цената на закупуване е 97, а погасителната стойност – 100. Ако се използва изчисляване с дневен баланс (основа 3), каква е дисконтовата ставка?

=DISC("2001-01-25";"2001-11-15";97;100;3) връща 0,0372 или 3,72%.

## DURATION

Изчислява времетраенето в години на ценна книга с фиксирана лихва.

#### Синтаксис

DURATION(Сделка; Падеж; Купон; Доходност; Честота [; Основа])

Сделка е датата на закупуване на ценната книга.

Падеж е датата на падежа на ценната книга, когато срокът й изтича.

Купон е годишната процентна ставка на купона на ценната книга.

Доходност е годишната доходност на ценната книга.

Честота е броят на купонните плащания за една година (1, 2 или 4).

Основа (незадължителен) се избира измежду няколко фиксирани възможности и указва как да се изчислява годината.

Основа | Пресмятане
--- | ---
0 или липсва | Американски метод (NASD) – 12 месеца с по 30 дни
1 | Точен брой дни в месеците, точен брой дни в година
2 | Точен брой дни в месеца, годината има 360 дни
3 | Точен брой дни в месеца, годината има 365 дни
4 | Европейски метод, 12 месеца по 30 дни всеки

#### Пример

Ценна книга е закупена на 01.01.2001 г., а датата на падежа й е 01.01.2006 г. Номиналният лихвен процент е 8%. Доходността е 9,0%. Лихвата се изплаща на полугодие (честотата е 2). Ако използваме дневен баланс (основа 3), колко е модифицираното времетраене?

=DURATION("2001-01-01"; "2006-01-01"; 0,08; 0,09; 2; 3) връща 4,2 години.

## EFFECT

Връща действителната годишна лихва за зададена номинална годишна лихва.

Номиналната лихва е дължимата лихва в края на разглеждания период. Действителната лихва нараства с броя на направените плащания. С други думи, лихвата често се плаща на вноски (например месечни или тримесечни) преди края на периода.

#### Синтаксис

EFFECT(Ном; П)

Ном е номиналната лихва.

П е броят на периодите на олихвяване за година.

#### Пример

Ако номиналната годишна лихва е 9,75% и олихвяването се извършва четири пъти годишно, каква е действителната лихва?

=EFFECT(9,75%;4) = 10,11% – следователно действителната годишна лихва е 10,11%.

## EFFECT_ADD

Връща действителната годишна лихва при зададена номинална годишна лихва и брой на периодите на олихвяване за година.

Функциите, чиито имена завършват с _ADD или _EXCEL2003, връщат същите резултати като съответните функции на Microsoft Excel 2003 без този суфикс. Функциите без суфикс връщат резултати, базирани на международните стандарти.

#### Синтаксис

EFFECT_ADD(НоминалнаЛихва; БрПерОл)

НоминалнаЛихва е номиналната лихва.

БрПерОл е броят на периодите на олихвяване за година.

#### Пример

Каква е действителната годишна лихва при номинална лихва от 5,25% и тримесечни плащания?

=EFFECT_ADD(0,0525; 4) връща 0,053543 или 5,3534%.

## IRR

Връща вътрешната норма на печалба за инвестиция. Числовите стойности представят парични потоци, постъпващи през регулярни интервали, като поне една стойност трябва да е отрицателна (плащане) и поне една – положителна (приход).

Ако плащанията се извършват през неравномерни интервали, използвайте функцията XIRR.

#### Синтаксис

IRR(Стойности [; Предположение])

Стойности представлява масив, съдържащ стойностите.

Предположение (незадължителен) е приблизителна стойност за резултата. Вътрешната норма на печалба се изчислява по итеративен метод. Ако можете да дадете само няколко стойности, трябва да зададете начално предположение, на което да се базират итерациите.

Тази функция игнорира текстовете и празните клетки в диапазон с данни. Ако подозирате, че резултатът ѝ е погрешен, потърсете текст в диапазоните с данни. За да осветите текстовото съдържание в диапазон с данни, използвайте функционалността за осветяване на стойности.

#### Пример

Ако предположим, че съдържанията на клетките са A1=-10000, A2=3500, A3=7600 и A4=1000, формулата =IRR(A1:A4) дава резултат 11,33%.

Заради използвания итеративен метод е възможно IRR да приключи с неуспех и да върне Грешка 523, с „Грешка: изчислението не е сходящо“ в реда на състоянието. В такъв случай изпробвайте друга стойност за „Предположение“.

## ISPMT

Изчислява лихвата при равномерни амортизационни плащания за инвестиция.

#### Синтаксис

ISPMT(Лихва; Период; БрПериоди; Инвестиция)

Лихва е лихвеният процент за един период.

Период е броят периоди за изчисляване на лихвата.

БрПер е общият брой периоди на плащане за инвестицията.

Инвестиция е стойността на инвестицията.

#### Пример

За заем в размер на 120 000 парични единици с двугодишен срок, месечни плащания и годишна лихва от 12% трябва да се изчисли лихвата след 1,5 години.

=ISPMT(1%;18;24;120000) = -300 парични единици. Месечната лихва след 1,5 години е 300 парични единици.

## PV

Връща настоящата стойност на инвестиция, получена от поредица регулярни плащания.

Използвайте тази функция, за да изчислите сумата, която трябва да се инвестира при фиксирана лихва днес, за да се получи определена сума (анюитет) за даден брой периоди. Можете да определите и колко пари трябва да останат след изтичането на периода, както и да зададете дали сумата се изплаща в началото или края на всеки период.

Въведете стойностите като числа, изрази или обръщения. Например, ако лихвата се изплаща годишно и е 8%, но вие искате да използвате месец като период, въведете 8%/12 за Лихва и LibreOffice Calc автоматично ще изчисли правилния коефициент.

#### Синтаксис

PV(Лихва; БрПер; ПерВн [; БъдСт [; Тип]])

Лихва е лихвеният процент за един период.

БрПер е общият брой периоди на плащане.

ПерВн е вноската, изплащана за всеки период.

БъдСт (незадължителен) е бъдещата стойност, която искате да се достигне след последната вноска.

Тип (незадължителен) указва датата за плащанията. Тип = 1 означава плащане в началото на периода, а Тип = 0 (по подразбиране) – плащане в края на периода.

Във функциите на LibreOffice Calc параметрите, отбелязани като „незадължителни“, могат да се пропускат само ако след тях не следват още параметри. Например, ако функцията приема четири параметъра, от които последните два са незадължителни, можете да изпуснете четвъртия параметър или третия и четвъртия, но не и само третия.

#### Пример

Каква е настоящата стойност на инвестиция, ако месечно се изплащат 500 парични единици, а годишният лихвен процент е 8%? Анюитетът е 48 месеца и накрая трябва да останат 20 000 парични единици.

=PV(8%/12;48;500;20000) = -35019,37 парични единици. При тези условия трябва да депозирате 35 019,37 парични единици днес, ако желаете да получавате 500 парични единици на месец в продължение на 48 месеца и накрая да останат 20 000 парични единици. Проверката показва, че 48 x 500 парични единици + 20 000 парични единици = 44 000 парични единици. Разликата между тази сума и вложените 35 000 парични единици представлява изплатената лихва.

Ако въведете обръщения вместо конкретни стойности във формулата, можете да изпробвате произволен брой сценарии от типа „Какво, ако“. Забележете, че обръщенията трябва да са абсолютни. Примери за този вид употреба можете да намерите при функциите за амортизации.

## RECEIVED

Връща сумата, получена при падежа за напълно инвестирана ценна книга..

#### Синтаксис

RECEIVED(Сделка; Падеж; Инвестиция; Дисконто [; Основа])

Сделка е датата на закупуване на ценната книга.

Падеж е датата на падежа на ценната книга, когато срокът й изтича.

Инвестиция е сумата, инвестирана в ценната книга.

Дисконто е дисконтовата ставка на ценната книга.

Основа (незадължителен) се избира измежду няколко фиксирани възможности и указва как да се изчислява годината.

Основа | Пресмятане
--- | ---
0 или липсва | Американски метод (NASD) – 12 месеца с по 30 дни
1 | Точен брой дни в месеците, точен брой дни в година
2 | Точен брой дни в месеца, годината има 360 дни
3 | Точен брой дни в месеца, годината има 365 дни
4 | Европейски метод, 12 месеца по 30 дни всеки

#### Пример

Дата на сделката: 15 февруари 1999 г., дата на падежа: 15 май 1999 г., инвестирана сума: 1000 парични единици, дисконтова ставка: 5,75%, основа: дневен баланс/360 = 2.

Получената сума на датата на падежа се изчислява както следва:

=RECEIVED("15.2.99";"15.5.99";1000;0,0575;2) връща 1014,420266.

## SYD

Изчислява амортизация по метода на снижаващия се остатък.

Тази функция служи за изчисляване на амортизациите за един период от полезния живот на актива. При метода на снижаващия се остатък амортизационната норма намалява с фиксирана сума от период на период.

#### Синтаксис

SYD(ОтчСтойност; ЛиквСтойност; Срок; Период)

ОтчСтойност е началната стойност на актива.

ЛиквСтойност е остатъчната стойност на актива в края на амортизационния срок.

Срок e броят периоди, за който активът се обезценява.

Период е периодът, за който се изчислява амортизацията.

#### Пример

За видеосистема с начална цена 50 000 парични единици трябва да се изчисли годишна амортизация за следващите 5 години. Ликвидационната стойност е 10 000 парични единици. Искаме да изчислим амортизацията за първата година.

=SYD(50000;10000;5;1)=13333,33 парични единици. Амортизационните отчисления за първата година са 13 333,33 парични единици.

За да получите обща представа за нормата на амортизация за всеки период, най-добре е да създадете амортизационна таблица. Въвеждайки една до друга различните формули за амортизация, достъпни в LibreOffice Calc, можете да видите кой метод на изчисляване е най-подходящ. Въведете таблицата както следва:

| A | B | C | D | E
1 | Отчетна стойност | Ликв. стойност | Полезен живот | Период | Аморт. SYD
2 | 50 000 парични единици | 10 000 парични единици | 5 | 1 | 13 333,33 парични единици
3 |  |  |  | 2 | 10 666,67 парични единици
4 |  |  |  | 3 | 8000,00 парични единици
5 |  |  |  | 4 | 5333,33 парични единици
6 |  |  |  | 5 | 2666,67 парични единици
7 |  |  |  | 6 | 0,00 парични единици
8 |  |  |  | 7 |
9 |  |  |  | 8 |
10 |  |  |  | 9 |
11 |  |  |  | 10 |
12 |  |  |  |  |
13 | >0 |  |  | Общо | 40 000,00 парични единици

Формулата в E2 е както следва:

=SYD($A$2; $B$2; $C$2; D2)

Тази формула се повтаря в колоната E до E11 (изберете E2, после плъзнете надолу долния десен ъгъл с мишката).

Клетката E13 съдържа формулата, с която се проверява общата сума на амортизационните отчисления. В нея е използвана функцията SUMIF , тъй като отрицателните стойности в E8:E11 не трябва да се взимат предвид. Условието >0 е в клетката A13. Формулата в E13 е както следва:

=SUMIF(E2:E11; A13)

Сега можете да разгледате амортизацията за десетгодишен период или с ликвидационна стойност от една парична единица, или да въведете различна отчетна стойност и т.н.

Финансови функции, втора част

Финансови функции, трета част

Функции по категория

Моля, подкрепете ни!