Περιεχόμενα

# LibreLogo

Το LibreLogo είναι ένα απλό, τοπικοποιημένο, περιβάλλον προγραμματισμού παρόμοιο με Logo με γραφικά διανύσματος χελώνας για διδασκαλία υπολογιστών (προγραμματισμός και επεξεργασία λέξεων), DTP και σχεδίαση γραφικών. Δείτε http://www.numbertext.org/logo/librelogo.pdf.

## Γραμμή εργαλείων LibreLogo

Η γραμμή εργαλείων LibreLogo (Προβολή - Γραμμές εργαλείων - Logo) περιέχει την κινούμενη χελώνα, έναρξη προγράμματος, διακοπή, αρχική θέση, καθαρισμό οθόνης, εικονίδια επισήμανσης/μετάφρασης επεξεργαστή/σύνταξης προγράμματος και μια γραμμή εισόδου (γραμμή εντολών).

## Εικονίδια μετακίνησης χελώνας

Είναι ισοδύναμα με τις εντολές Logo “ΜΠΡΟΣΤΑ 10”, “ΠΙΣΩ 10”, “ΑΡΙΣΤΕΡΑ 15”, “ΔΕΞΙΑ 15”. Πατώντας ένα από τα εικονίδια θα εστιάσει επίσης στο σχήμα της χελώνας κυλώντας τη σελίδα στη θέση της.

## Έναρξη προγράμματος Logo

Πατήστε στο εικονίδιο “Έναρξη προγράμματος Logo” για να εκτελέσετε το κείμενο (ή μόνο το επιλεγμένο κείμενο) του εγγράφου Writer ως προγράμματος LibreLogo. Σε ένα κενό έγγραφο ένα πρόγραμμα με παράδειγμα θα εισαχθεί και θα εκτελεστεί.

Πατήστε στο εικονίδιο “Διακοπή” για να σταματήσετε την εκτέλεση του προγράμματος.

## Αρχή

Πατήστε στο εικονίδιο “Αρχή” για να επαναφέρετε τη θέση και τις ρυθμίσεις της χελώνας.

## Καθαρισμός οθόνης

Πατήστε στο εικονίδιο “Καθαρισμός οθόνης” για να αφαιρέσετε τα αντικείμενα σχεδίασης του εγγράφου.

## Επεξεργαστής/επισήμανση σύνταξης/μετάφραση προγράμματος

Το εικονίδιο "μαγικό ραβδί" ορίζει διάταξη 2 σελίδων για επεξεργασία προγράμματος, επεκτείνει και μετατρέπει σε κεφαλαία τις συντομευμένες εντολές Logo με πεζά στο έγγραφο Writer. Αλλάξτε τη γλώσσα του εγγράφου (LibreOffice - Προτιμήσεις Εργαλεία - Επιλογές - Γλώσσες και τοπικές ρυθμίσεις - Γενικά - Δυτικά) και πατήστε σε αυτό το εικονίδιο για να μεταφράσετε το πρόγραμμα Logo στην επιλεγμένη γλώσσα.

## Γραμμή εντολών

Πατήστε εισαγωγή στη γραμμή εντολών για να εκτελέσετε το περιεχόμενό της. Για να διακόψετε το πρόγραμμα χρησιμοποιήστε το εικονίδιο “Διακοπή”.

Κρατήστε πατημένη την εισαγωγή για να επαναλάβετε τη γραμμή εντολών, για παράδειγμα, με την ακόλουθη σειρά εντολών:

     ΜΠΡΟΣΤΑ 200 ΑΡΙΣΤΕΡΑ 89

Για να επαναφέρετε τη γραμμή εντολών τριπλοπατήστε ή πατήστε Command Ctrl +A για να επιλέξετε τις προηγούμενες εντολές και πληκτρολογήστε τις νέες εντολές.

## Η γραφική διεπαφή χρήστη των βασικών ρυθμίσεων της χελώνας

Το σχήμα χελώνας του LibreLogo είναι ένα κανονικό αντικείμενο σχεδίασης σταθερού μεγέθους. Μπορείτε επίσης να το τοποθετήσετε και να το περιστρέψετε με τυπικό τρόπο, χρησιμοποιώντας το ποντίκι και το εικονίδιο περιστροφής της γραμμής εργαλείων ιδιοτήτων αντικειμένου σχεδίασης. Τροποποιήστε τις ρυθμίσεις πάχους γραμμής, χρώματος γραμμής και χρώματος περιοχής του σχήματος χελώνας για να ορίσετε τα χαρακτηριστικά PENSIZE, PENCOLOR και FILLCOLOR του LibreLogo.

## Επεξεργασία προγράμματος

Τα σχέδια LibreLogo και τα προγράμματα χρησιμοποιούν το ίδιο έγγραφο Writer. Ο καμβάς του LibreLogo είναι στην πρώτη σελίδα του εγγράφου Writer. Μπορείτε να εισάγετε μια αλλαγή σελίδας πριν τα προγράμματα LibreLogo και να ορίσετε την εστίαση σελίδας χρησιμοποιώντας το εικονίδιο “μαγικό ραβδί” της γραμμής εργαλείων Logo, αλλάξτε επίσης το μέγεθος γραμματοσειράς για μια άνετη διάταξη 2 σελίδων για τον προγραμματισμό LibreLogo: αριστερή (πρώτη) σελίδα είναι ο καμβάς, δεξιά (δεύτερη) σελίδα είναι ο επεξεργαστής προγράμματος LibreLogo.

# Η γλώσσα προγραμματισμού LibreLogo

Το LibreLogo είναι μια εύκολη τοπικοποιημένη γλώσσα προγραμματισμού παρόμοια με Logo, σε πολλές γλώσσες από τις τοπικές κοινότητες γλώσσας του LibreOffice. Είναι συμβατή προς τα πίσω με τα παλιότερα συστήματα Logo στην περίπτωση των απλών προγραμμάτων Logo που χρησιμοποιούνται στην εκπαίδευση, πχ.

     ΣΕ τρίγωνο :μέγεθος
     ΕΠΑΝΑΛΗΨΗ 3 [
       ΜΠΡΟΣΤΑ :μέγεθος
       ΑΡΙΣΤΕΡΑ 120
     ]
     ΤΕΛΟΣ

     τρίγωνο 10 τρίγωνο 100 τρίγωνο 200

## Διαφορές από τη γλώσσα προγραμματισμού Logo

- Τα μέλη του καταλόγου χωρίζονται με κόμμα: ΘΕΣΗ [0, 0]

- Οι ομάδες προγράμματος και οι κατάλογοι είναι διαφορετικοί

- - Οι ομάδες προγράμματος χρειάζονται κενό ή νέα γραμμή σε αγκύλες: ΕΠΑΝΑΛΗΨΗ 10 [ ΜΠΡΟΣΤΑ 10 ΑΡΙΣΤΕΡΑ 36 ]

  - Οι κατάλογοι χρειάζονται κλειστές αγκύλες: ΘΕΣΗ [0, 0] και όχι ΘΕΣΗ [ 0, 0 ]

- Οι δηλώσεις συνάρτησης 1 γραμμής δεν υποστηρίζονται (ΣΕ και ΤΕΛΟΣ χρειάζονται νέες γραμμές).

## Άλλα γνωρίσματα του LibreLogo

- Η τελεία είναι προαιρετική πριν από τα ονόματα μεταβλητών.

       Το μέγεθος τριγώνου
         ΕΠΑΝΑΛΗΨΗ 3 [ ΜΠΡΟΣΤΑ μέγεθος ΑΡΙΣΤΕΡΑ 120 ]
       ΤΕΛΟΣ

- Η σημειογραφία συμβολοσειρών υποστηρίζει επίσης σύνταξη ορθογραφίας και Python.

       ΤΥΠΩΣΕ "λέξη ; αρχική σύνταξη λογότυπου
       ΤΥΠΩΣΕ “Ελεύθερο κείμενο.” ; ορθογραφία, Writer
       ΤΥΠΩΣΕ 'Ελεύθερο κείμενο.' ; σύνταξη Python

- Κατάλογος Python και χειρισμός συμβολοσειρών

       ΤΥΠΩΣΕ “κείμενο”[2] ; τύπωσε “x”
       ΤΥΠΩΣΕ “κείμενο”[1:3] ; τύπωσε “χι”

- Παρόμοιος με Python βρόχος FOR

- Δήλωση μεταβλητής παρόμοια με Python:

       x = 15
       ΤΥΠΩΣΕ x

- Δεν υπάρχουν πρόσθετες συναρτήσεις ερωτημάτων:

       ΕΚΤΥΠΩΣΗ ΧΡΩΜΑΓΕΜΙΣΜΑΤΟΣ
       θ = ΘΕΣΗ
       ΤΥΠΩΣΕ θ
       ΕΠΑΝΑΛΗΨΗ 10 [ ΒΑΛΕ ΚΑΘΕ ΘΕΣΗ Θ ]

- Εναλλακτικές παρενθέσεις σε κλήσεις συνάρτησης

       ΣΕ χρώμα μεγέθους αστεριού
       χρώμα FILLCOLOR
       ΕΠΑΝΑΛΗΨΗ 5 [ ΑΡΙΣΤΕΡΑ 72 ΜΠΡΟΣΤΑ μέγεθος ΔΕΞΙΑ 144 ΜΠΡΟΣΤΑ μέγεθος ]
       ΓΕΜΙΣΜΑ
       ΤΕΛΟΣ

       αστέρι 100 "κόκκινο"
       αστέρι(100, "πράσινο")
       αστέρι(100, "γαλάζιο")

# Εντολές LibreLogo

## Βασική σύνταξη

### Διάκριση πεζών και κεφαλαίων

Εντολές, σταθερές χρώματος είναι ανεξάρτητες από πεζά-κεφαλαία:

     ΤΥΠΩΣΕ “Γεια σου, κόσμε!”
     τύπωσε “Γεια σου, κόσμε, ξανά!”

Τα ονόματα μεταβλητών κάνουν διάκριση πεζών/κεφαλαίων:

     a = 5
     A = 7
     ΤΥΠΩΣΕ a
     ΤΥΠΩΣΕ A

### Γραμμές προγράμματος

Οι γραμμές ενός προγράμματος LibreLogo είναι παράγραφοι στο έγγραφο Writer. Μια γραμμή προγράμματος μπορεί να περιέχει πολλές εντολές:

     ΤΥΠΩΣΕ “Γεια σου, κόσμε!” ΤΥΠΩΣΕ “LibreLogo”

### Σχόλια

Γραμμές ή τμήματα γραμμής είναι σχόλια από ένα ; μέχρι το τέλος της γραμμής (παραγράφου):

     ; κάποια σχόλια
     ΤΥΠΩΣΕ 5 * 5 ; κάποια σχόλια

### Αλλαγές γραμμών προγράμματος σε πολλαπλές παραγράφους

Είναι δυνατό να αλλάξετε μια γραμμή προγράμματος σε περισσότερες παραγράφους χρησιμοποιώντας τον χαρακτήρα ~ στο τέλος της γραμμής:

     ΤΥΠΩΣΕ “Αυτό είναι ένα πολύ μακρύ ” + ~
           “μήνυμα προειδοποίησης”

## Μετακίνηση χελώνας

### ΜΠΡΟΣΤΑ (μπ)

     ΜΠΡΟΣΤΑ 10 ; μετακίνηση μπροστά 10pt (1pt = 1/72 inch)
     ΜΠΡΟΣΤΑ 10pt ; δείτε παραπάνω
     ΜΠΡΟΣΤΑ 0.5in ; μετακίνηση μπροστά 0.5 ίντσα (1 inch = 2.54 cm)
     ΜΠΡΟΣΤΑ 1" ; δείτε παραπάνω
     ΜΠ 1mm
     ΜΠ 1cm

### ΠΙΣΩ (πι)

     ΠΙΣΩ 10 ; μετακίνηση πίσω 10pt

### ΑΡΙΣΤΕΡΑ (lt)

     ΑΡΙΣΤΕΡΑ 90 ; αριστερόστροφη στροφή 90 μοιρών
     ΑΡΙΣΤΕΡΑ 90° ; δείτε παραπάνω
     ΑΡ 3h ; δείτε παραπάνω (θέση ρολογιού)
     ΑΡ κάθε ; στροφή σε μια τυχαία θέση

### ΔΕΞΙΑ (δξ)

     ΔΕΞΙΑ 90 ; δεξιόστροφη στροφή 90 μοιρών

### ΓΡΑΦΙΔΑΠΑΝΩ (γπ)

     ΓΡΑΦΙΔΑΠΑΝΩ ; η χελώνα θα μετακινηθεί χωρίς να σχεδιάσει

### ΓΡΑΦΙΔΑΚΑΤΩ (γκ)

     ΓΡΑΦΙΔΑΚΑΤΩ ; η χελώνα θα μετακινηθεί χωρίς να σχεδιάσει

### ΘΕΣΗ (θσ)

     ΘΕΣΗ [0, 0] ; στροφή και μετακίνηση στην πάνω αριστερή γωνία
     ΘΕΣΗ ΜΕΓΕΘΟΣΣΕΛΙΔΑΣ ; στροφή και μετακίνηση στην κάτω δεξιά γωνία
     ΘΕΣΗ [ΜΕΓΕΘΟΣΣΕΛΙΔΑΣ[0], 0] ; στροφή και μετακίνηση στην πάνω δεξιά γωνία
     ΘΕΣΗ ΚΑΘΕ ; στροφή και μετακίνηση σε τυχαία θέση

### ΕΠΙΚΕΦΑΛΙΔΑ (ορε)

     ΕΠΙΚΕΦΑΛΙΔΑ 0 ; στροφή βόρεια
     ΕΠΙΚΕΦΑΛΙΔΑ 12ω ; δείτε παραπάνω
     ΕΠΙΚΕΦΑΛΙΔΑ [0, 0] ; στροφή στην πάνω αριστερή γωνία
     ΕΠΙΚΕΦΑΛΙΔΑ ΚΑΘΕ ; στροφή προς μια τυχαία κατεύθυνση

## Άλλες εντολές χελώνας

### ΑΠΟΚΡΥΨΗΧΕΛΩΝΑΣ (αχ)

     ΑΠΟΚΡΥΨΗΧΕΛΩΝΑΣ ; απόκρυψη χελώνας (μέχρι την εντολή εμφάνισηχελώνας)

### ΕΜΦΑΝΙΣΗΧΕΛΩΝΑΣ (εε)

     ΕΜΦΑΝΙΣΗΧΕΛΩΝΑΣ ; εμφάνιση χελώνας

### ΑΡΧΗ

     ΑΡΧΗ; επαναφορά αρχικής θέσης χελώνας

### ΚΑΘΑΡΙΣΜΟΣΟΘΟΝΗΣ (κο)

     ΚΑΘΑΡΙΣΜΟΣΟΘΟΝΗΣ ; αφαίρεση αντικειμένων σχεδίασης από το έγγραφο

### ΓΕΜΙΣΜΑ και ΚΛΕΙΣΙΜΟ

     ΓΕΜΙΣΜΑ ; κλείσιμο και συμπλήρωση του τρέχοντος σχήματος γραμμής ή σημείων
     ΚΛΕΙΣΙΜΟ ; κλείσιμο του τρέχοντος σχήματος γραμμής ή ένωση των τρεχόντων σημείων

Παράδειγμα: συμπλήρωση ενός κανονικού τριγώνου:

     ΜΠΡΟΣΤΑ 50 ΑΡΙΣΤΕΡΑ 120 ΜΠΡΟΣΤΑ 50 ΓΕΜΙΣΜΑ

Παράδειγμα: σχεδίαση ενός κανονικού τριγώνου:

     ΜΠΡΟΣΤΑ 50 ΑΡΙΣΤΕΡΑ 120 ΠΙΣΩ 50 ΚΛΕΙΣΙΜΟ

## Ρυθμίσεις γραφίδας

### ΜΕΓΕΘΟΣΓΡΑΦΙΔΑΣ (μγ)

     PENSIZE 100 ; line thickness is 100 points
     PENSIZE ANY ; equivalent of PENSIZE RANDOM 10

### ΧΡΩΜΑΓΡΑΦΙΔΑΣ (χγ)

     ΧΡΩΜΑΓΡΑΦΙΔΑΣ “κόκκινο” ; ορισμός κόκκινου χρώματος γραφίδας (κατά όνομα χρώματος, δείτε σταθερές χρώματος)
     ΧΡΩΜΑΓΡΑΦΙΔΑΣ [255, 255, 0] ; ορισμός κίτρινου χρώματος (κατάλογος RGB)
     ΧΡΩΜΑΓΡΑΦΙΔΑΣ 0xffff00 ; ορισμός κίτρινου χρώματος (δεκαεξαδικός κώδικας)
     ΧΡΩΜΑΓΡΑΦΙΔΑΣ 0 ; ορισμός μαύρου χρώματος (0x000000)
     ΧΡΩΜΑΓΡΑΦΙΔΑΣ ΚΑΘΕ ; τυχαίο χρώμα
     ΧΡΩΜΑΓΡΑΦΙΔΑΣ [5] ; ορισμός κόκκινου χρώματος (κατά ταυτοποιητή χρώματος, δείτε σταθερές χρώματος)
     ΧΡΩΜΑΓΡΑΦΙΔΑΣ “αόρατο” ; αόρατο χρώμα γραφίδας για σχήματα χωρίς ορατό περίγραμμα
     ΧΡΩΜΑΓΡΑΦΙΔΑΣ “~κόκκινο” ; ορισμός τυχαίου κόκκινου χρώματος

### ΔΙΑΦΑΝΕΙΑΓΡΑΦΙΔΑΣ

     ΔΙΑΦΑΝΕΙΑΓΡΑΦΙΔΑΣ 80 ; ορίζει τη διαφάνεια του ενεργού χρώματος γραφίδας σε 80%

### ΑΚΡΟΓΡΑΦΙΔΑΣ/ΑΚΡΟΓΡΑΜΜΗΣ

     ΑΚΡΟΓΡΑΦΙΔΑΣ “κανένα” ; χωρίς πρόσθετο τέλος γραμμής (προεπιλογή)
     ΑΚΡΟΓΡΑΦΙΔΑΣ “στρογγυλό” ; στρογγυλεμένο τέλος γραμμής
     ΑΚΡΟΓΡΑΦΙΔΑΣ “τετράγωνο” ; τετράγωνο τέλος γραμμής

### ΕΝΩΣΗΓΡΑΦΙΔΑΣ/ΕΝΩΣΗΓΡΑΜΜΗΣ

     ΕΝΩΣΗΓΡΑΦΙΔΑΣ “στρογγυλεμένο” ; στρογγυλεμένη ένωση γραμμής (προεπιλογή)
     ΕΝΩΣΗΓΡΑΦΙΔΑΣ “μύτη” ; οξεία ένωση γραμμής
     ΕΝΩΣΗΓΡΑΦΙΔΑΣ “λοξό” ; λοξή ένωση γραμμής
     ΕΝΩΣΗΓΡΑΦΙΔΑΣ “καμία” ; χωρίς ένωση γραμμής

### ΜΟΡΦΗΓΡΑΦΙΔΑΣ

     ΜΟΡΦΗΓΡΑΦΙΔΑΣ “συμπαγής” ; συμπαγής γραμμή (προεπιλογή)
     ΜΟΡΦΗΓΡΑΦΙΔΑΣ “διάστικτη” ; διάστικτη γραμμή
     ΜΟΡΦΗΓΡΑΦΙΔΑΣ “με παύλες” ; γραμμή με παύλες

     ; προσαρμοσμένο μοτίβο κουκκίδα-παύλα οριζόμενο από έναν κατάλογο με τα ακόλουθα ορίσματα:
     ; – αριθμός των γειτονικών κουκκίδων
     ; – μήκος κουκκίδας
     ; – αριθμός με γειτονικές παύλες
     ; – μήκος παύλας
     ; – απόσταση των κουκκίδων/παυλών
     ; – τύπος (προαιρετικό):
     ;   0 = οι κουκκίδες είναι ορθογώνιες (προεπιλογή)
     ;   2 = οι κουκκίδες είναι τετράγωνες (μήκη και αποστάσεις είναι σχετικές με το μέγεθος της γραφίδας)

     ΜΟΡΦΗΓΡΑΦΙΔΑΣ [3, 1mm, 2, 4mm, 2mm, 2] ; ...––...––...––

## Ρυθμίσεις γεμίσματος

### ΧΡΩΜΑΓΕΜΙΣΜΑΤΟΣ/ΧΡΩΜΑΓΕΜΙΣΜΑΤΟΣ (χε)

     ΧΡΩΜΑΓΡΑΦΙΔΑΣ “γαλάζιο” ; γέμισμα με γαλάζιο χρώμα, δείτε επίσης ΧΡΩΜΑΓΡΑΦΙΔΑΣ
     ΧΡΩΜΑΓΡΑΦΙΔΑΣ “αόρατο” ΚΥΚΛΟΣ 10 ; μη γεμάτος κύκλος
     ΧΡΩΜΑΓΕΜΙΣΜΑΤΟΣ [“γαλάζιο”, “κόκκινο”] ; διαβάθμιση μεταξύ κόκκινου και γαλάζιου
     ΧΡΩΜΑΓΕΜΙΣΜΑΤΟΣ [[255, 255, 255], [255, 128, 0]] ; μεταξύ λευκού και πορτοκαλί
     ΧΡΩΜΑΓΕΜΙΣΜΑΤΟΣ [“γαλάζιο”, “κόκκινο”, 1, 0, 0] ; ορισμός αξονικής διαβάθμισης (με την απαιτούμενη περιστροφή και ρυθμίσεις περιγράμματος), δυνατές τιμές: 0-5 = γραμμικές, αξονικές, ακτινικές, ελλειπτικές, τετραγωνικές και ορθογώνιες διαβαθμίσεις
     ΧΡΩΜΑΓΕΜΙΣΜΑΤΟΣ [“κόκκινο”, “γαλάζιο”, 0, 90, 20] ; γραμμικό με 20% περίγραμμα, περιεστραμμένο κατά 90 μοίρες ως προς την ενεργή επικεφαλίδα της χελώνας
     ΧΡΩΜΑΓΕΜΙΣΜΑΤΟΣ [“κόκκινο”, 'γαλάζιο”, 0, 90, 20, 0, 0, 200, 50] ; από 200% μέχρι 50% ένταση
     ΧΡΩΜΑΓΕΜΙΣΜΑΤΟΣ [ΚΑΘΕ, ΚΑΘΕ, 2, 0, 0, 50, 50] ; ακτινική διαβάθμιση με τυχαία χρώματα και 50-50% οριζόντιες και κάθετες θέσεις του κέντρου

### ΔΙΑΦΑΝΕΙΑΓΕΜΙΣΜΑΤΟΣ

     ΔΙΑΦΑΝΕΙΑΓΕΜΙΣΜΑΤΟΣ 80 ; ορισμός της διαφάνειας του ενεργού χρώματος γεμίσματος σε 80%
     ΔΙΑΦΑΝΕΙΑΓΕΜΙΣΜΑΤΟΣ [80] ; ορισμός γραμμικής διαβάθμισης διαφάνειας από 80% μέχρι 0%
     ΔΙΑΦΑΝΕΙΑΓΕΜΙΣΜΑΤΟΣ [80, 20] ; ορισμός γραμμικής διαβάθμισης διαφάνειας από 80% μέχρι 20%
     ΔΙΑΦΑΝΕΙΑΓΕΜΙΣΜΑΤΟΣ [80, 20, 1, 90] ; ορισμός αξονικής διαβάθμισης διαφάνειας περιεστραμμένης κατά 90 μοίρες ως προς την ενεργή επικεφαλίδα της χελώνας
     ΔΙΑΦΑΝΕΙΑΓΕΜΙΣΜΑΤΟΣ [80, 20, 2, 0, 20, 50, 50] ; ορισμός ακτινικής διαβάθμισης διαφάνειας από εξωτερική διαφάνεια 80% σε εσωτερική 20% με περίγραμμα 20% και με οριζόντιες και κάθετες θέσεις του κέντρου 50-50%

### ΜΟΡΦΗΓΕΜΙΣΜΑΤΟΣ

     ΜΟΡΦΗΓΕΜΙΣΜΑΤΟΣ 0 ; γέμισμα χωρίς διαγραμμίσεις (προεπιλογή)
     ΜΟΡΦΗΓΕΜΙΣΜΑΤΟΣ 1 ; μαύρες απλές διαγραμμίσεις (οριζόντιες)
     ΜΟΡΦΗΓΕΜΙΣΜΑΤΟΣ 2 ; μαύρες απλές διαγραμμίσεις (45 μοίρες)
     ΜΟΡΦΗΓΕΜΙΣΜΑΤΟΣ 3 ; μαύρες απλές διαγραμμίσεις (-45 μοίρες)
     ΜΟΡΦΗΓΕΜΙΣΜΑΤΟΣ 4 ; μαύρες απλές διαγραμμίσεις (κάθετες)
     ΜΟΡΦΗΓΕΜΙΣΜΑΤΟΣ 5 ; κόκκινες σταυρωτές διαγραμμίσεις (45 μοίρες)
     ΜΟΡΦΗΓΕΜΙΣΜΑΤΟΣ 6 ; κόκκινες σταυρωτές διαγραμμίσεις (0 μοίρες)
     ΜΟΡΦΗΓΕΜΙΣΜΑΤΟΣ 7 ; γαλάζιες σταυρωτές διαγραμμίσεις (45 μοίρες)
     ΜΟΡΦΗΓΕΜΙΣΜΑΤΟΣ 8 ; γαλάζιες σταυρωτές διαγραμμίσεις (0 μοίρες)
     ΜΟΡΦΗΓΕΜΙΣΜΑΤΟΣ 9 ; γαλάζιες τριπλές σταυρωτές
     ΜΟΡΦΗΓΕΜΙΣΜΑΤΟΣ 10 ; μαύρες πλατιές απλές διαγραμμίσεις (45 μοίρες)

     ; προσαρμοσμένες διαγραμμίσεις οριζόμενες από έναν κατάλογο με τα ακόλουθα ορίσματα
     ; – τεχνοτροπία (1 = απλή, 2 = διπλή, 3 = τριπλή διαγράμμιση)
     ; – χρώμα
     ; – απόσταση
     ; – μοίρες

     ΜΟΡΦΗΓΕΜΙΣΜΑΤΟΣ [2, “πράσινο”, 3pt, 15°] ; πράσινες σταυρωτές διαγραμμίσεις (15 μοίρες)

## Αντικείμενα σχεδίασης

### ΚΥΚΛΟΣ

     ΚΥΚΛΟΣ 100 ; σχεδίαση σχήματος κύκλου (διάμετρος = 100pt)

### ΕΛΛΕΙΨΗ

     ΕΛΛΕΙΨΗ [50, 100] ; σχεδίαση έλλειψης με διαμέτρους 50 και 100
     ELLIPSE [50, 100, 2h, 12h] ; σχεδίαση ελλειπτικού τομέα (από τη θέση ρολογιού 2ω μέχρι 12ω)
     ΕΛΛΕΙΨΗ [50, 100, 2h, 12h, 2]  ; σχεδίαση ελλειπτικού τμήματος
     ΕΛΛΕΙΨΗ [50, 100, 2h, 12h, 3]  ; σχεδίαση ελλειπτικού τόξου

### ΤΕΤΡΑΓΩΝΟ

     ΤΕΤΡΑΓΩΝΟ 100 ; σχεδίαση σχήματος τετραγώνου (μέγεθος = 100pt)

### ΟΡΘΟΓΩΝΙΟ

     ΟΡΘΟΓΩΝΙΟ [50, 100] ; σχεδίαση ορθογώνιου σχήματος (50×100pt)
     ΟΡΘΟΓΩΝΙΟ [50, 100, 10] ; σχεδίαση ορθογωνίου με στρογγυλεμένες γωνίες

### ΣΗΜΕΙΟ

     ΣΗΜΕΙΟ ; σχεδίαση στιγμής με μέγεθος και χρώμα της γραφίδας

Το ΚΛΕΙΣΙΜΟ μπορεί να ενώσει τα τελευταία σημεία, το ΓΕΜΙΣΜΑ μπορεί να συμπληρώσει το σχήμα που ορίζεται από τα σημεία. Παραδείγματος χάρη, είναι εύκολη η σχεδίαση ενός “επίπεδου” αστεριού ξεκινώντας από το κέντρο του:

     ΓΡΑΦΙΔΑΠΑΝΩ
     ΕΠΑΝΑΛΗΨΗ 5 [
     ΜΠΡΟΣΤΑ 80
    ΣΗΜΕΙΟ
     ΠΙΣΩ 80
     ΔΕΞΙΑ 36
     ΜΠΡΟΣΤΑ 50
     ΣΗΜΕΙΟ
     ΠΙΣΩ 50
     ΔΕΞΙΑ 120
     ] ΓΕΜΙΣΜΑ

### ΕΤΙΚΕΤΑ

     ΕΤΙΚΕΤΑ “κείμενο” ; εκτύπωση κειμένου στη θέση χελώνας
     ΕΤΙΚΕΤΑ 'κείμενο' ; δείτε παραπάνω
     ΕΤΙΚΕΤΑ "κείμενο ; δείτε παραπάνω (μόνο για μεμονωμένες λέξεις)

### ΚΕΙΜΕΝΟ

     ΚΥΚΛΟΣ 10 ΚΕΙΜΕΝΟ “κείμενο” ; ορισμός κειμένου του τρέχοντος σχεδίου

## Ρυθμίσεις γραμματοσειρών

### ΧΡΩΜΑΓΡΑΜΜΑΤΟΣΕΙΡΑΣ

     ΧΡΩΜΑΓΡΑΜΜΑΤΟΣΕΙΡΑΣ “πράσινο” ; ορισμός χρώματος γραμματοσειράς

### ΟΙΚΟΓΕΝΕΙΑΓΡΑΜΜΑΤΟΣΕΙΡΑΣ

     ΟΙΚΟΓΕΝΕΙΑΓΡΑΜΜΑΤΟΣΕΙΡΑΣ “Linux Libertine G” ; ορισμός γραμματοσειράς (οικογένειας)
     ΟΙΚΟΓΕΝΕΙΑΓΡΑΜΜΑΤΟΣΕΙΡΑΣ “Linux Libertine G:smcp=1” ; ορισμός επίσης γνωρίσματος γραμματοσειράς (μικρά κεφαλαία)
     ΟΙΚΟΓΕΝΕΙΑΓΡΑΜΜΑΤΟΣΕΙΡΑΣ “Linux Libertine G:smcp=1&onum=1” ; μικρά κεφαλαία + παλιές μορφές

### ΜΕΓΕΘΟΣΓΡΑΜΜΑΤΟΣΕΙΡΑΣ

     ΜΕΓΕΘΟΣΓΡΑΜΜΑΤΟΣΕΙΡΑΣ 12 ; ορισμός 12 στιγμών

### ΠΑΧΟΣΓΡΑΜΜΑΤΟΣΕΙΡΑΣ

     ΠΑΧΟΣΓΡΑΜΜΑΤΟΣΕΙΡΑΣ “έντονα” ; ορισμός έντονης γραμματοσειράς
     ΠΑΧΟΣΓΡΑΜΜΑΤΟΣΕΙΡΑΣ “κανονικό” ; ορισμός κανονικού πάχους

### ΜΟΡΦΗΓΡΑΜΜΑΤΟΣΕΙΡΑΣ

     ΜΟΡΦΗΓΡΑΜΜΑΤΟΣΕΙΡΑΣ “πλάγια” ; ορισμός παραλλαγής πλαγίων
     ΜΟΡΦΗΓΡΑΜΜΑΤΟΣΕΙΡΑΣ “κανονικά” ; ορισμός παραλλαγής κανονικών

## ΕΙΚΟΝΑ (εικ)

Η ΕΙΚΟΝΑ είναι για

- ομαδοποίηση σχημάτων;

- έναρξη νέας σχημάτων γραμμής;

- αποθήκευση εικόνων SVG και κινήσεων SVG/SMIL·

- διατήρηση της σταθερότητας των θέσεων και σχημάτων γραμμών στο αριστερό άκρο.

### Ομαδοποίηση σχημάτων

     ; ΕΙΚΟΝΑ [ LibreLogo_commands ]
     ΕΙΚΟΝΑ [ ΜΠΡΟΣΤΑ 100 ΚΥΚΛΟΣ 100 ] ; δενδροειδές ομαδοποιημένο σχήμα

Δείτε επίσης την "Ομαδοποίηση" στη Βοήθεια του Writer στο LibreOffice.

     ΣΕ θέση δένδρου
       ΓΡΑΦΙΔΑΠΑΝΩ ΘΕΣΗ τοποθεσία ΕΠΙΚΕΦΑΛΙΔΑ 0 ΓΡΑΦΙΔΑΚΑΤΩ
       ΕΙΚΟΝΑ [ ΜΠΡΟΣΤΑ 100 ΚΥΚΛΟΣ 100 ] ; δενδροειδές ομαδοποιημένο σχήμα
     ΤΕΛΟΣ

     ΕΙΚΟΝΑ [ δένδρο [230, 400] δένδρο [300, 400] ] ; ομαδοποιημένα σχήματα σε ένα ομαδοποιημένο σχήμα

### Έναρξη νέας σχημάτων γραμμής

     ΕΙΚΟΝΑ ; έναρξη σχήματος νέας γραμμής
     ΜΠΡΟΣΤΑ 10 ΕΙΚΟΝΑ ΜΠΡΟΣΤΑ 10 ; δύο σχήματα γραμμών

### Αποθήκευση εικόνων SVG

     ΕΙΚΟΝΑ “example.svg” [ΚΥΚΛΟΣ 5 ] ; αποθήκευση της εικόνας ως αρχείο εικόνας SVG στον φάκελο χρήστη
     ΕΙΚΟΝΑ “Επιφάνεια εργασίας//example.svg” [ ΜΠΡΟΣΤΑ 100 ΚΥΚΛΟΣ 5 ] ; όπως παραπάνω, με σχετική διαδρομή
     ΕΙΚΟΝΑ “/home/user/example.svg” [ ΚΥΚΛΟΣ 5 ] ; απόλυτη διαδρομή για Γιούνιξ/Λίνουξ
     ΕΙΚΟΝΑ “C:\example.svg” [ ΚΥΚΛΟΣ 5 ] ; απόλυτη διαδρομή για Windows

### Αποθήκευση κινήσεων SVG/SMIL (σχέδια με εντολές ΑΝΑΜΟΝΗ)

     ΕΙΚΟΝΑ “animation.svg” [ΚΥΚΛΟΣ 5 ΑΝΑΜΟΝΗ 1000 ΚΥΚΛΟΣ 99 ] ; αποθήκευση ως μια κίνηση SVG/SMIL (δείτε επίσης ΑΝΑΜΟΝΗ)
     ΕΙΚΟΝΑ “animation2.svg” [ ΚΥΚΛΟΣ 5 ΑΝΑΜΟΝΗ 1000 ΚΥΚΛΟΣ 99 ΑΝΑΜΟΝΗ 2000 ] ; όπως παραπάνω, αλλά χρησιμοποιώντας ΑΝΑΜΟΝΗ μετά το τελευταίο αντικείμενο θα καταλήξει σε βρόχο: μετά από 2 δευτερόλεπτα η κίνηση SVG ξαναρχίζει σε περιηγητές συμβατούς με SMIL

### Σταθερότητα στο αριστερό άκρο

Χρησιμοποιήστε ΕΙΚΟΝΑ για να διατηρήσετε τη σταθερότητα θέσεων και σχημάτων γραμμών στο αριστερό άκρο του Writer:

     ΕΙΚΟΝΑ [ ΚΥΚΛΟΣ 20 ΘΕΣΗ [-100, 100] ΚΥΚΛΟΣ 20 ]

## Βρόχοι

### ΕΠΑΝΑΛΗΨΗ

     ; ΕΠΑΝΑΛΗΨΗ αριθμού [ εντολές ]

     ΕΠΑΝΑΛΗΨΗ 10 [ ΜΠΡΟΣΤΑ 10 ΑΡΙΣΤΕΡΑ 45 ΚΥΚΛΟΣ 10 ] ; επανάληψη 10 φορές

     ; ο αριθμός είναι προαιρετικός

     ΕΠΑΝΑΛΗΨΗ [ ΘΕΣΗ ΚΑΘΕ ] ; ατέρμων βρόχος

### ΑΡΙΘΜΟΣΕΠΑΝΑΛΗΨΕΩΝ

Μεταβλητή βρόχου (επίσης για βρόχους στο ΓΙΑΟΣΟ και ΟΣΟ).

     ΕΠΑΝΑΛΗΨΗ 100 [ ΜΠΡΟΣΤΑ ΑΡΙΘΜΟΣΕΠΑΝΑΛΗΨΕΩΝ ΑΡΙΣΤΕΡΑ 90 ]

### ΓΙΑΟΣΟ ΣΤΟ

Βρόχος για τα στοιχεία του καταλόγου:

     ΓΙΑΟΣΟ i ΣΤΟ [1, 5, 7, 9, 11] [
       ΜΠΡΟΣΤΑ i
       ΑΡΙΣΤΕΡΑ 90
     ]

Βρόχος για τους χαρακτήρες μιας αλληλουχίας χαρακτήρων:

     ΓΙΑΟΣΟ i ΣΤΟ “text” [
       ΕΤΙΚΕΤΑ i
       ΜΠΡΟΣΤΑ 10
     ]

### ΟΣΟ

     ΟΣΟ ΑΛΗΘΗΣ [ ΘΕΣΗ ΚΑΘΕ ] ; ατελείωτος βρόχος
     ΟΣΟ ΑΡΙΘΜΟΣΕΠΑΝΑΛΗΨΕΩΝ <= 10 [ ΜΠΡΟΣΤΑ 50 ΑΡΙΣΤΕΡΑ 36 ] ; ως ΕΠΑΝΑΛΗΨΗ 10 [ ... ]

### ΔΙΑΚΟΠΗ

Τερματισμός του βρόχου.

     ΕΠΑΝΑΛΗΨΗ [ ; ατελείωτος βρόχος
       ΘΕΣΗ ΚΑΘΕ
       ΑΝ ΑΡΙΘΜΟΣΕΠΑΝΑΛΗΨΕΩΝ = 100 [ ΔΙΑΚΟΠΗ ]  ; ισοδύναμο του ΕΠΑΝΑΛΗΨΗ 100 [ ... ]
     ]

### ΣΥΝΕΧΕΙΑ

Μετάβαση στην επόμενη επανάληψη του βρόχου.

     ΕΠΑΝΑΛΗΨΗ 100 [
       ΘΕΣΗ ΚΑΘΕ
       ΑΝ ΑΡΙΘΜΟΣΕΠΑΝΑΛΗΨΕΩΝ % 2 = 0 [ ΣΥΝΕΧΕΙΑ ]
       ΚΥΚΛΟΣ 10 ; σχεδίαση κύκλων σε κάθε 2η θέση
     ]

## Συνθήκες

### ΑΝ

     ; ΑΝ συνθήκη [ αληθής ομάδα ]
     ; ΑΝ συνθήκη [ αληθής ομάδα ] [ ψευδής ομάδα ]

     ΑΝ a < 10 [ ΕΚΤΥΠΩΣΗ “Μικρό” ]
     ΑΝ a < 10 [ ΕΚΤΥΠΩΣΗ “Μικρό” ] [ ΕΚΤΥΠΩΣΗ “Μεγάλο” ]

### ΚΑΙ, Ή, ΟΧΙ

Λογικοί τελεστές.

     ΑΝ a < 10 ΚΑΙ ΟΧΙ a = 5 [ ΕΚΤΥΠΩΣΗ “0, 1, 2, 3, 4, 6, 7, 8 ή 9” ]
     ΑΝ a < 10 ΚΑΙ a != 5 [ ΕΚΤΥΠΩΣΗ “0, 1, 2, 3, 4, 6, 7, 8 ή 9” ] ; όπως παραπάνω

## Υπορουτίνες

### ΣΕ, ΤΕΛΟΣ

Νέα λέξη (ή διεργασία).

     ΣΕ τρίγωνο
       ΕΠΑΝΑΛΗΨΗ 2 [ ΜΠΡΟΣΤΑ 100 ΔΕΞΙΑ 120 ] ΓΕΜΙΣΜΑ
     ΤΕΛΟΣ

     ΕΠΑΝΑΛΗΨΗ 10 [ τρίγωνο ΓΡΑΦΙΔΑΠΑΝΩ ΘΕΣΗ ΚΑΘΕ ΓΡΑΦΙΔΑΚΑΤΩ ]

### ΕΞΟΔΟΣ

Επιστροφή της τιμής της συνάρτησης.

     ΣΕ τυχαίο γράμμα
       ΕΞΟΔΟΣ ΤΥΧΑΙΟ “qwertzuiopasdfghjklyxcvbnm”
     ΤΕΛΟΣ

     ΕΚΤΥΠΩΣΗ τυχαίο γράμμα + τυχαίο γράμμα + τυχαίο γράμμα ; εκτύπωση τυχαίας σειράς χαρακτήρων 3 γραμμάτων

### ΤΕΡΜΑΤΙΣΜΟΣ

Επιστροφή από τη διαδικασία.

     ΣΕ παράδειγμα αριθμού
       ΑΝ αριθμός< 0 [ ΤΕΡΜΑΤΙΣΜΟΣ ]
       ΕΚΤΥΠΩΣΗ ΤΕΤΡΑΓΩΝΙΚΗΡΙΖΑ αριθμού ; εκτύπωση τετραγωνικής ρίζας
     ]

     παράδειγμα 100
     παράδειγμα -1 ; χωρίς έξοδο και σφάλμα
     παράδειγμα 25

## Προεπιλεγμένες μεταβλητές

### ΚΑΘΕ

Τυχαία προεπιλεγμένη τιμή χρωμάτων, κλπ.

     ΧΡΩΜΑΓΡΑΦΙΔΑΣ ΚΑΘΕ ; τυχαίο χρώμα γραφίδας

### ΑΛΗΘΗΣ

Λογική τιμή.

     ΟΣΟ ΑΛΗΘΗΣ [ ΘΕΣΗ ΚΑΘΕ ] ; ατέρμων βρόχος
     ΤΥΠΩΣΕ ΑΛΗΘΗΣ ; τύπωσε αληθές

### ΨΕΥΔΗΣ

Λογική τιμή.

     ΟΣΟ ΟΧΙ ΨΕΥΔΗΣ [ ΘΕΣΗ ΚΑΘΕ ] ; ατέρμων βρόχος
     ΤΥΠΩΣΕ ΨΕΥΔΗΣ ; τύπωσε ψευδές

### ΜΕΓΕΘΟΣΣΕΛΙΔΑΣ

     ΕΚΤΥΠΩΣΗ ΜΕΓΕΘΟΣΣΕΛΙΔΑΣ ; εκτύπωση καταλόγου των μεγεθών σελίδας σε στιγμές, πχ. [595.30, 841.89]

### ΠΙ/π

     ΤΥΠΩΣΕ ΠΙ ; τύπωσε 3.14159265359

## Είσοδος/Έξοδος

### ΤΥΠΩΣΕ

     ΤΥΠΩΣΕ “κείμενο” ; τύπωσε “κείμενο” σε ένα πλαίσιο διαλόγου
     ΕΚΤΥΠΩΣΗ 5 + 10 ; τύπωσε 15

### ΕΙΣΟΔΟΣ

     ΤΥΠΩΣΕ ΕΙΣΟΔΟΣ “Τιμή εξόδου;” ; ερώτηση και εκτύπωση μιας συμβολοσειράς από ένα πλαίσιο διαλόγου ερωτήματος
     ΤΥΠΩΣΕ ΚΙΝΗΤΗΥΠΟΔΙΑΣΤΟΛΗ (ΕΙΣΟΔΟΣ “Πρώτος αριθμός;”) + ΚΙΝΗΤΗΥΠΟΔΙΑΣΤΟΛΗ (ΕΙΣΟΔΟΣ “Δεύτερος αριθμός”) ; απλή αριθμομηχανή

## ΑΝΑΜΟΝΗ

     ΑΝΑΜΟΝΗ 1000 ; αναμονή για 1000 ms (1 sec)

## ΚΑΘΟΛΙΚΟ

Ορισμός καθολικών μεταβλητών που χρησιμοποιούνται σε διεργασίες.

     ΚΑΘΟΛΙΚΟ περί
     περί = “LibreLogo”

     ΣΕ παράδειγμα
       ΤΥΠΩΣΕ περί
       ΚΑΘΟΛΙΚΟ περί ; όταν θέλουμε να προσθέσουμε μια νέα τιμή
       περί = “νέα τιμή για την καθολική μεταβλητή”
     ΤΕΛΟΣ

     παράδειγμα
     ΤΥΠΩΣΕ περί

## Συναρτήσεις

### ΤΥΧΑΙΟ

     ΤΥΠΩΣΕ ΤΥΧΑΙΟ 100 ; τυχαίος αριθμός κινητής υποδιαστολής(0 <= x < 100)
     ΤΥΠΩΣΕ ΤΥΧΑΙΟ “κείμενο” ; τυχαίο γράμμα του “κειμένου”
     ΤΥΠΩΣΕ ΤΥΧΑΙΟ [1, 2] ; τυχαίο στοιχείο καταλόγου (1 ή 2)

### ΑΚΕΡΑΙΟ

     ΤΥΠΩΣΕ ΑΚΕΡΑΙΟΣ 3.8 ; τύπωσε 3 (ακέραιο μέρος του 3.8)
     ΤΥΠΩΣΕ ΑΚΕΡΑΙΟΣ ΤΥΧΑΙΟΣ 100 ; τυχαίος ακέραιος αριθμός (0 <= x < 100)
     ΤΥΠΩΣΕ ΑΚΕΡΑΙΟΣ “7” ; μετατροπή της παραμέτρου συμβολοσειράς σε ακέραιο

### ΚΙΝΗΤΗΥΠΟΔΙΑΣΤΟΛΗ

     ; μετατροπή της παραμέτρου συμβολοσειράς σε αριθμό κινητής υποδιαστολής
     ΤΥΠΩΣΕ 2 * ΚΙΝΗΤΗΥΠΟΔΙΑΣΤΟΛΗ “5.5” ; τύπωσε 11.0

### ΣΥΜΒΟΛΟΣΕΙΡΑ

     ; μετατροπή της αριθμητικής παραμέτρου σε συμβολοσειρά
     ΤΥΠΩΣΕ “Αποτέλεσμα: ” + ΣΥΜΒΟΛΟΣΕΙΡΑ 5 ; τύπωσε “Αποτέλεσμα: 5”
     ΤΥΠΩΣΕ 10 * ΣΥΜΒΟΛΟΣΕΙΡΑ 5 ; τύπωσε 5555555555

### ΤΕΤΡΑΓΩΝΙΚΗΡΙΖΑ

     ΤΥΠΩΣΕ ΤΕΤΡΑΓΩΝΙΚΗΡΙΖΑ 100 ; τύπωσε 10, τετραγωνική ρίζα του 100

### ΗΜΙΤΟΝΟ

     ΤΥΠΩΣΕ ΗΜΙΤΟΝΟ 90 * ΠΙ/180 ; τύπωσε 1.0 (ημίτονο 90° σε ακτίνια)

### ΣΥΝΗΜΙΤΟΝΟ

     ΤΥΠΩΣΕ ΣΥΝΗΜΙΤΟΝΟ 0 * ΠΙ/180 ; τύπωσε 1.0 (ημίτονο 0° σε ακτίνια)

### LOG10

     ΤΥΠΩΣΕ LOG10 100 ; ΤΎΠΩΣΕ 2.0 (κοινός λογάριθμος του 100)

### ΣΤΡΟΓΓΥΛΟΠΟΙΗΣΗ

     ΤΥΠΩΣΕ ΣΤΡΟΓΓΥΛΟΠΟΙΗΣΗ 3.8 ; τύπωσε 4 (στρογγυλοποίηση 3.8)
     ΤΥΠΩΣΕ ΣΤΡΟΓΓΥΛΟΠΟΙΗΣΗ ΤΥΧΑΙΟ 100 ; τυχαίος ακέραιος αριθμός (0 <= x <= 100)

### ΑΠΟΛΥΤΟ

     ΤΥΠΩΣΕ ΑΠΟΛΥΤΟ -10 ; τύπωσε 10, απόλυτη τιμή του -10

### ΠΛΗΘΟΣ

     ΤΥΠΩΣΕ ΠΛΗΘΟΣ “κείμενο” ; τύπωσε 4, μέτρηση χαρακτήρων του “κειμένου”
     ΤΥΠΩΣΕ ΠΛΗΘΟΣ [1, 2, 3] ; τύπωσε 3, μέγεθος του καταλόγου

### ΟΡΙΣΜΟΣ

     ; μετατροπή καταλόγου σε σύνολο Python
     ΤΥΠΩΣΕ ΣΥΝΟΛΟ [4, 5, 6, 6] ; τύπωσε {4, 5, 6}
     ΤΥΠΩΣΕ ΣΥΝΟΛΟ[4, 5, 6, 6] | ΣΥΝΟΛΟ [4, 1, 9] ; τύπωσε {1, 4, 5, 6, 9}, ένωση
     ΤΥΠΩΣΕ ΣΥΝΟΛΟ [4, 5, 6, 6] & ΣΥΝΟΛΟ [4, 1, 9] ; τύπωσε {4}, τομή
     ΤΥΠΩΣΕ ΣΥΝΟΛΟ ([4, 5, 6, 6]) - ΣΥΝΟΛΟ [4, 1, 9] ; τύπωσε {5, 6}, διαφορά
     ΤΥΠΩΣΕ ΣΥΝΟΛΟ [4, 5, 6, 6] ^ ΣΥΝΟΛΟ [4, 1, 9] ; τύπωσε {1, 5, 6, 9}, συμμετρική διαφορά

### ΠΕΡΙΟΧΗ

     ; γενιά καταλόγων παρόμοιων με Python
     PRINT LIST RANGE 10 ; print [0, 1, 2, 3, 4, 5, 6, 7, 8, 9]
     PRINT LIST RANGE 3 10 ; print [3, 4, 5, 6, 7, 8, 9]
     PRINT LIST RANGE 3 10 3 ; print [3, 6, 9]

     FOR i IN RANGE 10 50 10 [ ; loop for [10, 20, 30, 40]
       FORWARD i
       LEFT 90
     ]

### ΚΑΤΑΛΟΓΟΣ

     ; αφαίρεση των επαναλαμβανόμενων στοιχείων ενός καταλόγου χρησιμοποιώντας ορισμό και μετατροπή καταλόγου
     ΤΥΠΩΣΕ ΚΑΤΑΛΟΓΟ (ΣΥΝΟΛΟ [1, 3, 5, 5, 2, 1]) ; τύπωσε [1, 3, 5, 2]

### ΠΛΕΙΑΔΑ

Μετατροπή σε πλειάδα Python (μη τροποποιήσιμος κατάλογος)

     ΤΥΠΩΣΕ ΠΛΕΙΑΔΑ [4, 5]

### ΤΑΞΙΝΟΜΗΜΕΝΑ

Επιστρέφει έναν ταξινομημένο κατάλογο.

     ΤΥΠΩΣΕ ΤΑΞΙΝΟΜΗΜΕΝΑ [5, 1, 3, 4] ; τύπωσε [1, 3, 4, 5]

### ΑΝΤΙΚΑΤΑΣΤΑΣΗ

Αντικατάσταση σειράς χαρακτήρων χρησιμοποιώντας μοτίβα regex (κανονικής έκφρασης).

     ΤΥΠΩΣΕ ΑΝΤΙΚΑΤΑΣΤΑΣΗ (“κ”, “Κ”, “κείμενο”) ; τύπωσε “Κείμενο”, αντικαθιστώντας “κ” με “Κ”
     ΤΥΠΩΣΕ ΑΝΤΙΚΑΤΑΣΤΑΣΗ (“(.)”, “\\1\\1”, “κείμενο”) ; τύπωσε “κκεείίμμεεννοο”, διπλασιάζοντας κάθε χαρακτήρα

### ΑΝΑΖΗΤΗΣΗ

Αναζήτηση μοτίβων σειράς χαρακτήρων χρησιμοποιώντας μοτίβα regex.

     ΑΝ ΑΝΑΖΗΤΗΣΗ (“\λ”, "λέξη") [ ΤΥΠΩΣΕ “Γράμμα στη λέξη.” ]

### ΕΥΡΕΣΗΟΛΩΝ

Εύρεση όλων των σειρών χαρακτήρων στη συμβολοσειρά εισόδου που ταιριάζει το δεδομένο μοτίβο regex.

     ΤΥΠΩΣΕ ΕΥΡΕΣΗΟΛΩΝ(“\λ+”, “Σκυλιά, γάτες.”) ; τύπωσε [“Σκυλιά”, “γάτες”], ο κατάλογος των λέξεων.

### ΕΛΑΧΙΣΤΟ

     ΤΥΠΩΣΕ ΕΛΑΧΙΣΤΟ [1, 2, 3] ; τύπωσε 1, το μικρότερο στοιχείο του καταλόγου

### ΜΕΓΙΣΤΟ

     ΤΥΠΩΣΕ ΜΕΓΙΣΤΟ [1, 2, 3] ; τύπωσε 3, το μεγαλύτερο στοιχείο του καταλόγου

## Σταθερές χρώματος

     ΧΡΩΜΑΓΡΑΦΙΔΑΣ “ΑΣΗΜΙ” ; ορισμός κατά όνομα
     ΧΡΩΜΑΓΡΑΦΙΔΑΣ [1] ; ορισμός κατά ταυτοποιητή
     ΧΡΩΜΑΓΡΑΦΙΔΑΣ “~ΑΣΗΜΙ” ; τυχαίο ασημένιο χρώμα

Ταυτοποιητής | Όνομα
--- | ---
0 | ΜΑΥΡΟ
1 | ΑΣΗΜΙ
2 | ΓΚΡΙΖΟ
3 | ΛΕΥΚΟ
4 | ΚΑΣΤΑΝΟΚΟΚΚΙΝΟ
5 | ΚΟΚΚΙΝΟ
6 | PURPLE
7 | ΦΟΥΞΙΑ/ΜΑΤΖΕΝΤΑ
8 | ΠΡΑΣΙΝΟ
9 | ΛΕΜΟΝΙ
10 | ΛΑΔΙ
11 | ΚΙΤΡΙΝΟ
12 | ΘΑΛΑΣΣΙ
13 | ΓΑΛΑΖΙΟ
14 | TEAL
15 | ΝΕΡΟ
16 | ΡΟΖ
17 | ΤΟΜΑΤΙ
18 | ΠΟΡΤΟΚΑΛΙ
19 | ΧΡΥΣΑΦΙ
20 | ΒΙΟΛΕΤΙ
21 | ΟΥΡΑΝΙ
22 | ΣΟΚΟΛΑΤΙ
23 | ΚΑΦΕΤΙ
24 | ΑΟΡΑΤΟ

Παρακαλούμε, υποστηρίξτε μας!